#version 430 core

layout(location = 0) in vec3 pos;
layout(location = 1) in vec3 norm;
layout(location = 2) in vec2 tex;
layout(location = 3) in ivec4 boneIds; 
layout(location = 4) in vec4 weights;
	
uniform mat4 proj;
uniform mat4 view;
uniform mat4 modl;

uniform mat4 lightSpaceMatrix;

const int MAX_BONES = 100;
const int MAX_BONE_INFLUENCE = 4;
uniform mat4 finalBonesMatrices[MAX_BONES];
	
out vec3 normal;
out vec2 texCoord;
out vec3 FragPos;
out vec4 fragposlightspace;

uniform int uvMode = 0;                // 0 = stretch, 1 = tile
uniform vec3 tileScale = vec3(1.0);
uniform vec2 uvOffset = vec2(0.0);

// Same direction as transpose(inverse(m)) for normals, without the per vertex inverse
mat3 CofactorMatrix(mat3 m)
{
    return mat3(cross(m[1], m[2]), cross(m[2], m[0]), cross(m[0], m[1]));
}

// Tiling ignores the mesh's uvs and projects from whichever axis the surface faces.
// Done on the bind pose, so the pattern stays stuck to the character as it moves.
vec2 SurfaceUV()
{
    if (uvMode == 0) return tex + uvOffset;

    vec3 n = abs(norm);
    vec3 p = pos * tileScale;
    if (n.y >= n.x && n.y >= n.z) return p.xz + uvOffset;
    if (n.x >= n.z) return p.zy + uvOffset;
    return p.xy + uvOffset;
}

void main()
{
    vec4 totalPosition = vec4(0.0);
    vec3 totalNormal = vec3(0.0);

    int bonescontributed = 0;
    for(int i = 0; i < MAX_BONE_INFLUENCE; i++)
    {
        if(boneIds[i] == -1) continue;
        if(boneIds[i] >= MAX_BONES)
        {
            totalPosition = vec4(pos, 1.0);
            totalNormal = norm;
            break;
        }
        bonescontributed ++;
        totalPosition += (finalBonesMatrices[boneIds[i]] * vec4(pos, 1.0))* weights[i];
        totalNormal   += mat3(finalBonesMatrices[boneIds[i]]) * norm * weights[i];
    }
    vec4 worldPos    = modl * totalPosition;
    FragPos          = worldPos.xyz;
    fragposlightspace = lightSpaceMatrix * worldPos;
    gl_Position      = proj * view * worldPos;
    normal           = normalize(CofactorMatrix(mat3(modl)) * totalNormal);
    texCoord         = SurfaceUV();
}